VISTA.HDSI.SUBCHEMHEMTOXRIASERetcExtended Modifications 2013-04-22

**Class:** VISTA.HDSI.SUBCHEMHEMTOXRIASERetcExtended

**Columns:**

* ConcatenatedResultsExt – concatenated results from file (63.04) and returns information based on link to file 60 (Lab Test)
* ConcatenatedResultsManualExt – concatenate results from file (63.04) and returns information directly from global (63.04).  However, most data stored at the node is not documented in fileman so that is why this custom column is called “manual”.  They have to manually pull information out of the string.

**Purpose of change:**

CDS application displays test results by the test panel.  The way the CDS application was coded it was having issues when the panel value changed or was out of sequence in the concatenated results column (ConcatenatedResultsManualExt).  Typically tests done have the same panel value.  So for most sites this was not an issue.  However, there are some sites that have different panels for the same test.   This scenario was not tested or known by SQA.  There were two options to fix this issue, CDS could change their code or we could change sorting in the concatenated results columns.  Of the two options, making the change on the caché side seemed more suitable.  Mainly, we could push the change more quickly than CDS since it would not require a separate deployment and secondly array parsing is much easier to manage in caché than java.

**Change:**

Change the order the concatenated results appear in the string based on the panel value.  Sorting by panel value fixes the bug in the CDS application.  Before, they were concatenated based on the test node value, see example below:

**Example**:  Panel value (highlighted)

LR(24,"CH",6949681.976943,0)="3050317.023057^1^3050317.023315^11748^72^CH 0317 22^^^^20354^GM^^23;SC(^500"

                           2)="310^H\*^84330.0000!!!3096!!!175^11748^72!60!110!50!300!!mg/dL!!!^^^^500"

                           6)="5.2^^84140.0000!!!3096!!!177^11748^72!3.8!5.3!3!6!!meq/L!2!5^^^^500"

                           7)="100^^84330.0000!!!3096!!!178^11748^72!95!108!80!120!!meq/L!2!4^^^^500"

**Before change**: Sort based on the node value.  It would concatenate results as:  <Node 2 info>,<Node 6 info>,<Node 7 info>

**Column return**: 310^H\*^84330.0000!!!3096!!!175^11748^72!60!110!50!300!!mg/dL!!!^^^^500, 5.2^^84140.0000!!!3096!!!177^11748^72!3.8!5.3!3!6!!meq/L!2!5^^^^500, 100^^84330.0000!!!3096!!!178^11748^72!95!108!80!120!!meq/L!2!4^^^^500

**After change**: Sort based panel value.  It would concatenate results as: <Node 2 info>,<Node 7 info>,<Node 6 info>

**Column return**: 310^H\*^84330.0000!!!3096!!!175^11748^72!60!110!50!300!!mg/dL!!!^^^^500, 100^^84330.0000!!!3096!!!178^11748^72!95!108!80!120!!meq/L!2!4^^^^500, 5.2^^84140.0000!!!3096!!!177^11748^72!3.8!5.3!3!6!!meq/L!2!5^^^^500

**Code Change:**  Load results into a sparse array based on the panel value and then generated concatenated string from sparse array.  Modified code is highlighted:

ClassMethod getResults(RowId As %String, Option As %String) As %String

                q:RowId="" ""  
                S lrdfn=$P(RowId,"||",1),IDT=$P(RowId,"||",2)  
                q:lrdfn=""!(IDT="") ""  
                s node=1,ret="",cnt=0  
                k retarr  
                  
                ; loop through the Result nodes. Result nodes start at node 2 upto the first non numeric node  
    while node {  
                    s err="",manFlg=0  
                    s node=+$O(^LR(lrdfn,"CH",IDT,node))  
                    if node <2 continue   ;Result fields start at row 2  
                    s resultData=$g(^LR(lrdfn,"CH",IDT,node))   
                    s result=$p(resultData,"^") if result="" continue  
                    If $zconvert(result,"u")="PENDING" continue  ; Per CDS on 2/21/2013, skip results that have a pending value  
                    s cnt=cnt+1    
                    s panel=$p($p(resultData,"^",3),"!",1) ;panel info appears here...need to sort all test by panel  
                    s:panel="" panel="ZZ"  ;make it sort last  
                                if $l($p(resultData,result,2))>1 s manFlg=1 ;If there is anything after the result then pass it into the ConcatenatedResultsManualExt Column  
                                s loc="CH;"\_node\_";1"  
                    s dd="DD(63.04,"\_node\_","  
                    s ddname=$P($G(^DD(63.04,node,0)),"^")  
                    if ddname="" continue  
  
                    ; check to see if results is a set of codes value...if so then send the translated value  
                    if $P($G(^DD(63.04,node,0)),"^",2)="S" {  
                                    s fndFlg=0  
                                    s setofcodes=$P($G(^DD(63.04,node,0)),"^",3)  
                                    f pc=1:1:$l(setofcodes,";") if $p($p(setofcodes,";",pc),":",1)=result s result=$p($p(setofcodes,";",pc),":",2),pc=1000,fndFlg=1  
                                    if 'fndFlg s:err]"" err=err\_";" s err=err\_"Error: No matching SOC value found"  
                    }  
                      
                    ;Get the ptr value for the test in File# 60 (Laboratory Tests)  
                    s ptr=""  
                    if $d(^LAB(60,"C",loc)) {  
                                s qflg=0,ndx=""  
                                while qflg=0 {  
                                                s ndx=$o(^LAB(60,"C",loc,ndx))  
                                                if ndx="" s qflg=1 continue  
                                                s data=$g(^LAB(60,ndx,0))  
                                                if $p(data,"^")'=ddname continue  
                                                if $p(data,"^",12)'=dd continue  
                                                s ptr=ndx,qflg=1  
                                }  
                    }                
                                ;If ptr is null then it could not match on the ddname exactly...if this is the case then grab the first entry in the C xref  
                                s:ptr="" ptr=$o(^LAB(60,"C",loc,"")) ; Grabs the first value in the C Xref...assuming the lowest value is the first entry created and the best choice  
                                ;if ptr still null then truely there are no matching entries in file 60   
  
                                if ptr="" s:err]"" err=err\_";" s err=err\_"Error: No matching record found in File #60"  
                                ;per CDS they want test results to sort by panel value  
                                ;so load into a temporary array based on the panel value...added counter (cnt)   
                                ;because panel value can repeat  
                    I Option = 1 s retarr(panel,cnt)=result\_"^"\_ptr\_"^"\_ddname\_"^"\_err  
                    I Option=2&(manFlg) s retarr(panel,cnt)=ptr\_"\*"\_resultData  
                }                
                ;  
                s ret=""  
                s x="" f  s x=$o(retarr(x)) q:x=""  s y="" f  s y=$o(retarr(x,y)) q:y=""  s ret=ret\_$g(retarr(x,y))\_","                
                q ret  
}